# (c) 2023-present Eroax
# (c) 2023-present Yagich
# GNU General Public License v3.0+ (see COPYING or https://www.gnu.org/licenses/gpl-3.0.txt)
extends DeckNode

var noobs: NoOBSWS

var cached_scene_name: String
var cached_source_name: String
var cached_id # TODO: evaluate if this caching is actually needed


func _init() -> void:
	name = "Get Source ID"
	node_type = "obs_search_source"
	description = "Searches for an OBS source in a scene and returns its output."

	add_input_port(
		DeckType.Types.STRING,
		"Scene name",
		"field"
	)

	add_input_port(
		DeckType.Types.STRING,
		"Source name",
		"field"
	)

	add_output_port(
		DeckType.Types.NUMERIC,
		"Source ID"
	)


func _value_request(_on_output_port: int) -> Variant:
	if noobs == null:
		noobs = Connections.obs_websocket

	var scene_name: String
	if request_value(0) != null:
		scene_name = request_value(0)
	elif get_input_ports()[0].value_callback.get_object() && get_input_ports()[0].value_callback.call() != "":
		scene_name = get_input_ports()[0].value_callback.call()
	if scene_name.is_empty():
		return null

	var source_name: String
	if request_value(1) != null:
		source_name = request_value(1)
	elif get_input_ports()[1].value_callback.get_object() && get_input_ports()[1].value_callback.call() != "":
		source_name = get_input_ports()[1].value_callback.call()
	if source_name.is_empty():
		return null

	if cached_scene_name == scene_name && cached_source_name == scene_name:
		return cached_id
	
	cached_scene_name = scene_name
	cached_source_name = source_name

	var req := noobs.make_generic_request(
		"GetSceneItemId",
		{
			"scene_name": scene_name,
			"source_name": source_name
		}
	)
	await req.response_received

	var data := req.message.get_data()
	#if int(data.request_status.code) != NoOBSWS.Enums.RequestStatus.NO_ERROR:
		#return null
	cached_id = data.response_data.scene_item_id

	return data.response_data.scene_item_id